Escrever ou importar uma teoria

O TreeLevel não sabe de cor uma única regra de Feynman: ele as deduz da lagrangiana que você lhe dá. Duas maneiras de fornecê-la — um arquivo .feyn numa linguagem minúscula, ou uma pasta UFO gerada pelo FeynRules.

O princípio

Declaram-se os campos (spin, massa, largura, carga, cor) e os parâmetros, e depois escreve-se a lagrangiana de interação, termo a termo. Os termos cinéticos não se escrevem: os propagadores decorrem das declarações e do calibre escolhido. Todo termo com três campos ou mais vira um vértice:

$V = i\times\sum_{\text{atribuições pernas}\,\leftrightarrow\,\text{campos}}\bigl(\text{termo sem seus campos},\ \partial_\mu\to -ip_\mu,\ \text{momentos todos entrantes}\bigr)$

A soma sobre as maneiras de ligar as pernas aos campos produz os fatores combinatórios ( $-\lambda/4!\,\phi^4$ dá $-i\lambda$ ), as simetrizações dos vértices com bósons idênticos e, para férmions de Majorana ou acoplamentos com $C$ , a combinação $\Gamma + \Gamma'$ de Denner.

A linguagem `.feyn`

model QED
gauge feynman                       # feynman | unitary

param ee = 0.313451, Me = 0.000511  # parâmetros, valor numérico opcional
cparam V = 0.97                     # parâmetro complexo; conj(V) é o seu conjugado

field e  : dirac, mass Me, charge -1, pdg 11, label "e"
field mu : dirac, mass MMU, charge -1, pdg 13, label "μ"
field A  : vector, pdg 22, label "γ"
field Z  : vector, mass MZ, width WZ  # a largura entra no propagador
field u  : dirac, mass MU, charge 2/3, color 3
field G  : vector, color 8            # octeto: glúon
field N  : majorana, mass MN          # sua própria antipartícula
field h  : scalar, mass MH
field Gp : scalar, mass MW, charge 1, goldstone

family lep = { e, mu }                # campos de mesma estrutura
array  Q[lep] = { -1, -1 }            # parâmetros indexados por família
define W3[mu] = cw Z[mu] + sw A[mu]   # macro; seus índices mudos são renomeados a cada uso

L += sum(i in lep) ee Q[i] lep[i]~[a] gamma[nu][a,b] lep[i][b] A[nu]
L += gs u~[a,k] gamma[nu][a,b] T[c,k,l] u[b,l] G[nu,c]
L += -gs f[a,b,c] (del[mu] G[nu,a]) G[mu,b] G[nu,c]
L += -lam/24 h h h h                 # −λ/4! φ⁴ → vértice −iλ

Índices. Um nome de índice repetido num termo é contraído. Os campos levam seus índices nesta ordem: espinorial, depois cor (u[a,k]); Lorentz, depois cor adjunta (G[mu,c]). O tipo de um índice (Lorentz, espinorial, tripleto, octeto) decorre de sua posição.
Conjugação. X~ é o conjugado do campo X: e~ é $\bar e$ , W~ destrói um $W^-$ se W destrói um $W^+$ . Para um campo autoconjugado ( $\gamma, Z, h$ , Majorana), o til não tem efeito.
Tensores predefinidos. g (métrica), delta, gamma, gamma5, PL, PR, C (conjugação de carga), T (Gell-Mann/2), f (constantes de estrutura), eps — Levi-Civita, com quatro índices para Lorentz, com três para a cor.
Derivadas e constantes. del[mu] X; I; sqrt2; expoentes ^2 sobre parâmetros e números (um campo é repetido: h h h h); conj(...).
Férmions. Escreva as formas bilineares na ordem natural, $\bar\psi\,\Gamma\,\chi$ (o campo «linha» antes do campo «coluna»). majorana declara um campo autoconjugado de spin $\tfrac12$ : $\bar N\gamma^\mu\gamma^5N$ dá $2\gamma^\mu\gamma^5$ , e $\bar N\gamma^\mu N$ se anula, como deve ser.
Convenções. Vértice $= i\times$ termo, momentos entrantes, del[mu] → -I p[mu]. O Modelo Padrão embutido segue as convenções do FeynRules ( $D = \partial - igTA$ , $\Phi = \bigl(-iG^+,\ (v+h+iG^0)/\sqrt2\bigr)$ , calibre de Feynman); seus 129 vértices coincidem com os do UFO sm do MadGraph.

Erros de sintaxe, de índices (um mesmo nome usado como espinorial e como cor) ou de estrutura (uma matriz C que não une dois campos fermiônicos) são apontados — em inglês, com o número da linha, na aba Teoria.

Exemplo: acrescentar um Z′ ao Modelo Padrão

Na paleta, modelo StandardModel, botão Duplicar. O novo modelo «StandardModel cópia» fica selecionado; renomeie-o como SM-Zprime.

Aba Teoria. Acrescente, abaixo dos parâmetros e dos campos:

param gZp = 0.3, MZp = 3000, WZp = 30
field Zp : vector, mass MZp, width WZp, label "Z′"
# acoplamento vetorial universal aos léptons carregados
L += sum(i in lep) gZp lep[i]~[a] gamma[nu][a,b] lep[i][b] Zp[nu]

Aplicar. O Z′ aparece na paleta e a lista de vértices ganha três entradas.
Desenhe $e^+e^-\to\mu^+\mu^-$ e então Gerar: três diagramas ( $\gamma, Z, Z'$ ). Trace $\sigma$ de 200 a 5 000 GeV em escala logarítmica: a ressonância em 3 TeV tem exatamente a largura que você indicou. Para uma largura coerente, desenhe $Z'\to e^+e^-$ , leia $\Gamma$ na aba Cálculo e informe-a (× o número de canais) em WZp.

Acoplamentos que violam o número fermiônico

Diquarks, leptoquarks, bósons X e Y de uma grande unificação, termos de Majorana com campos de Dirac: esses acoplamentos unem dois campos «no mesmo sentido» — dois $\psi$ ou dois $\bar\psi$ — por meio da matriz de conjugação de carga $C = i\gamma^2\gamma^0$ ( $C^{T} = -C$ , $C\gamma^{\mu T}C^{-1} = -\gamma^\mu$ ):

# ψᵀ C Γ χ  =  ψ̄ᶜ Γ χ           (ψᶜ = C ψ̄ᵀ, ψ̄ᶜ = ψᵀ C)
L += -g5/sqrt2 d[a,k] C[a,b] gamma[mu][b,c] PL[c,d] e[d] X[mu,k]
# ψ̄ Γ C χ̄ᵀ  =  ψ̄ Γ χᶜ          (o conjugado hermitiano do anterior)
L += -g5/sqrt2 e~[a] gamma[mu][a,b] PL[b,c] C[c,d] d~[d,k] X~[mu,k]
# diquark: ε de cor, duas vezes o mesmo campo → regra Γ + Γ′
L += -g5/sqrt2 eps[k,l,m] u~[a,l] gamma[mu][a,b] PL[b,c] C[c,d] u~[d,m] X[mu,k]

O TreeLevel absorve $C$ na regra do vértice: a regra é $\Gamma$ entre a perna «linha» ( $\psi$ ou $\bar\psi$ ) e a perna «coluna», e é o fluxo fermiônico — orientado cadeia por cadeia segundo Denner, Eck, Hahn e Küblbeck — que carrega a conjugação: $\Gamma' = C\Gamma^{T}C^{-1}$ quando um vértice é percorrido ao contrário, $S(-p)$ para um propagador percorrido ao contrário, espinores $u, v, \bar u, \bar v$ conforme a posição na cadeia e não conforme partícula/antipartícula. O resultado não depende da orientação escolhida; os testes verificam isso em cada processo.

Duas identidades que o núcleo reproduz e que servem de sentinela: $\varepsilon_{klm}\,\bar u_l\gamma^\mu P_LC\bar u_m^{T} = \varepsilon_{klm}\,\bar u_l\gamma^\mu P_RC\bar u_m^{T}$ (o diquark do X se acopla às duas quiralidades, daí $\Gamma(X\to uu) = \Gamma(X\to e^+\bar d)$ ), e o acoplamento diquark axial $\varepsilon\,\bar u\gamma^\mu\gamma^5C\bar u^{T}$ se anula identicamente, assim como o acoplamento vetorial de um Majorana.

Importar um UFO

O formato UFO (Universal FeynRules Output) é a pasta Python que o FeynRules produz para o MadGraph e os demais geradores: particles.py, parameters.py, couplings.py, lorentz.py, vertices.py… O TreeLevel a lê diretamente, sem Python: um pequeno leitor de Python declarativo avalia os parâmetros internos (funções cmath, matrizes de mistura, expressões complexas), reconhece como Majorana os férmions autoconjugados e traduz cada estrutura de Lorentz e de cor numa regra.

Obtenha uma pasta UFO: de uma instalação do MadGraph (models/sm, models/MSSM_SLHA2…) ou da base de modelos do FeynRules.
Paleta › Modelo › 📁 Importar uma pasta UFO. A importação leva uma fração de segundo; o relatório indica campos, vértices, parâmetros e, se houver, os vértices ignorados e por quê.
O modelo fica em Meus modelos, pronto para a paleta, a geração e os cálculos numéricos e simbólicos. A aba Teoria mostra suas notas de importação.

Convenções aplicadas, fixadas sobre o UFO sm do MadGraph (129/129 vértices idênticos ao Modelo Padrão deduzido): listas de partículas e momentos todos saintes, Gamma(mu,i,j) $= (\gamma^\mu)_{ij}$ com $i$ do lado $\bar\psi$ , ProjM $= P_L$ , T(a,i,j) $= (T^a)_{ij}$ , Epsilon de cor com três índices. O MSSM_SLHA2 é importado por inteiro (50 campos, 1 572 parâmetros, 822 vértices); seus neutralinos e seu gluino são tratados como Majorana.

Um modelo importado conserva suas regras como estão: ele não tem lagrangiana editável no TreeLevel. As estruturas de Lorentz de quatro férmions (contato) e os vértices com C no UFO ainda não são traduzidos; aparecem nas notas de importação.

FeynRules, `.fr`, UFO, `.feyn`: quem faz o quê

Arquivo	Natureza	O que o TreeLevel faz com ele
`.fr`	Fonte Mathematica do FeynRules: campos, parâmetros, lagrangiana em notação Mathematica.	Não é lido diretamente (seria preciso o Mathematica). O FeynRules o exporta em UFO.
pasta UFO	Regras de Feynman já deduzidas, em Python declarativo.	Importada diretamente.
`.feyn`	A linguagem do TreeLevel: os mesmos ingredientes de um `.fr`, de forma mais concisa.	Deduzida na execução; editável no app.
`.feyndiag`	Documento TreeLevel.	Teoria + diagramas de um processo.

Transcrever um .fr num .feyn é hoje feito à mão e costuma ser questão de uma hora para um modelo de tamanho razoável: as convenções ( $D_\mu$ , projetores, normalizações) são as mesmas. Para um modelo grande, o caminho recomendado continua sendo .fr → UFO → importação.